rt-thread/bsp/realview-a8/SConstruct

import os
import sys
import rtconfig

if os.getenv('RTT_ROOT'):
    RTT_ROOT = os.getenv('RTT_ROOT')
else:
    RTT_ROOT = os.path.normpath(os.getcwd() + '/../..')

sys.path = sys.path + [os.path.join(RTT_ROOT, 'tools')]
from building import *

TARGET = 'rtthread-realview.' + rtconfig.TARGET_EXT

env = Environment(tools = ['mingw'],
	AS = rtconfig.AS, ASFLAGS = rtconfig.AFLAGS,
	CC = rtconfig.CC, CCFLAGS = rtconfig.CFLAGS,
	AR = rtconfig.AR, ARFLAGS = '-rc',
	LINK = rtconfig.LINK, LINKFLAGS = rtconfig.LFLAGS)
env.PrependENVPath('PATH', rtconfig.EXEC_PATH)

Export('RTT_ROOT')
Export('rtconfig')

# prepare building environment
objs = PrepareBuilding(env, RTT_ROOT)

if GetDepend('RT_USING_VMM'):
    if os.system('{cppcmd} -P -C -E -I. -D__ASSEMBLY__ {ldfile}.S -o {ldfile}'.format(
                  cppcmd = os.path.join(rtconfig.EXEC_PATH, 'arm-none-eabi-gcc'),
                  ldfile = rtconfig.LINK_SCRIPT)) != 0:
        print('failed to generate linker script %s' % rtconfig.LINK_SCRIPT)
        sys.exit(255)
    # if the linker script changed, relink the target
    Depends(TARGET, rtconfig.LINK_SCRIPT)
else:
    # we should use none-vmm link script
    link_flags = str(env['LINKFLAGS'])
    env['LINKFLAGS'] = link_flags.replace('_vmm.lds', '.lds')

# make a building
DoBuilding(TARGET, objs)